Andrew's git / gitweb.git / git-svnimport.perl
?
git-svnimport.perlon commit Don't output error on changes in the nodes /, /tags or /branches (c2c07a5)
   1#!/usr/bin/perl -w
   2
   3# This tool is copyright (c) 2005, Matthias Urlichs.
   4# It is released under the Gnu Public License, version 2.
   5#
   6# The basic idea is to pull and analyze SVN changes.
   7#
   8# Checking out the files is done by a single long-running SVN connection.
   9#
  10# The head revision is on branch "origin" by default.
  11# You can change that with the '-o' option.
  12
  13require 5.008; # for shell-safe open("-|",LIST)
  14use strict;
  15use warnings;
  16use Getopt::Std;
  17use File::Spec;
  18use File::Temp qw(tempfile);
  19use File::Path qw(mkpath);
  20use File::Basename qw(basename dirname);
  21use Time::Local;
  22use IO::Pipe;
  23use POSIX qw(strftime dup2);
  24use IPC::Open2;
  25use SVN::Core;
  26use SVN::Ra;
  27
  28die "Need CVN:Core 1.2.1 or better" if $SVN::Core::VERSION lt "1.2.1";
  29
  30$SIG{'PIPE'}="IGNORE";
  31$ENV{'TZ'}="UTC";
  32
  33our($opt_h,$opt_o,$opt_v,$opt_u,$opt_C,$opt_i,$opt_m,$opt_M,$opt_t,$opt_T,$opt_b,$opt_s,$opt_l,$opt_d,$opt_D);
  34
  35sub usage() {
  36        print STDERR <<END;
  37Usage: ${\basename $0}     # fetch/update GIT from CVS
  38       [-o branch-for-HEAD] [-h] [-v] [-l max_num_changes]
  39       [-C GIT_repository] [-t tagname] [-T trunkname] [-b branchname]
  40       [-d|-D] [-i] [-u] [-s start_chg] [-m] [-M regex] [SVN_URL]
  41END
  42        exit(1);
  43}
  44
  45getopts("b:C:dDhil:mM:o:s:t:T:uv") or usage();
  46usage if $opt_h;
  47
  48my $tag_name = $opt_t || "tags";
  49my $trunk_name = $opt_T || "trunk";
  50my $branch_name = $opt_b || "branches";
  51
  52@ARGV == 1 or @ARGV == 2 or usage();
  53
  54$opt_o ||= "origin";
  55$opt_s ||= 1;
  56$opt_l = 100 unless defined $opt_l;
  57my $git_tree = $opt_C;
  58$git_tree ||= ".";
  59
  60my $svn_url = $ARGV[0];
  61my $svn_dir = $ARGV[1];
  62
  63our @mergerx = ();
  64if ($opt_m) {
  65        @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
  66}
  67if ($opt_M) {
  68        push (@mergerx, qr/$opt_M/);
  69}
  70
  71select(STDERR); $|=1; select(STDOUT);
  72
  73
  74package SVNconn;
  75# Basic SVN connection.
  76# We're only interested in connecting and downloading, so ...
  77
  78use File::Spec;
  79use File::Temp qw(tempfile);
  80use POSIX qw(strftime dup2);
  81
  82sub new {
  83        my($what,$repo) = @_;
  84        $what=ref($what) if ref($what);
  85
  86        my $self = {};
  87        $self->{'buffer'} = "";
  88        bless($self,$what);
  89
  90        $repo =~ s#/+$##;
  91        $self->{'fullrep'} = $repo;
  92        $self->conn();
  93
  94        return $self;
  95}
  96
  97sub conn {
  98        my $self = shift;
  99        my $repo = $self->{'fullrep'};
 100        my $s = SVN::Ra->new($repo);
 101
 102        die "SVN connection to $repo: $!\n" unless defined $s;
 103        $self->{'svn'} = $s;
 104        $self->{'repo'} = $repo;
 105        $self->{'maxrev'} = $s->get_latest_revnum();
 106}
 107
 108sub file {
 109        my($self,$path,$rev) = @_;
 110
 111        my ($fh, $name) = tempfile('gitsvn.XXXXXX',
 112                    DIR => File::Spec->tmpdir(), UNLINK => 1);
 113
 114        print "... $rev $path ...\n" if $opt_v;
 115        my $pool = SVN::Pool->new();
 116        eval { $self->{'svn'}->get_file($path,$rev,$fh,$pool); };
 117        $pool->clear;
 118        if($@) {
 119                return undef if $@ =~ /Attempted to get checksum/;
 120                die $@;
 121        }
 122        close ($fh);
 123
 124        return $name;
 125}
 126
 127package main;
 128use URI;
 129
 130my $svn = $svn_url;
 131$svn .= "/$svn_dir" if defined $svn_dir;
 132$svn = SVNconn->new($svn);
 133
 134my $lwp_ua;
 135if($opt_d or $opt_D) {
 136        $svn_url = URI->new($svn_url)->canonical;
 137        if($opt_D) {
 138                $svn_dir =~ s#/*$#/#;
 139        } else {
 140                $svn_dir = "";
 141        }
 142        if ($svn_url->scheme eq "http") {
 143                use LWP::UserAgent;
 144                $lwp_ua = LWP::UserAgent->new(keep_alive => 1, requests_redirectable => []);
 145        } else {
 146                print STDERR "Warning: not HTTP; turning off direct file access\n";
 147                $opt_d=0;
 148        }
 149}
 150
 151sub pdate($) {
 152        my($d) = @_;
 153        $d =~ m#(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)#
 154                or die "Unparseable date: $d\n";
 155        my $y=$1; $y-=1900 if $y>1900;
 156        return timegm($6||0,$5,$4,$3,$2-1,$y);
 157}
 158
 159sub getwd() {
 160        my $pwd = `pwd`;
 161        chomp $pwd;
 162        return $pwd;
 163}
 164
 165
 166sub get_headref($$) {
 167    my $name    = shift;
 168    my $git_dir = shift;
 169    my $sha;
 170
 171    if (open(C,"$git_dir/refs/heads/$name")) {
 172        chomp($sha = <C>);
 173        close(C);
 174        length($sha) == 40
 175            or die "Cannot get head id for $name ($sha): $!\n";
 176    }
 177    return $sha;
 178}
 179
 180
 181-d $git_tree
 182        or mkdir($git_tree,0777)
 183        or die "Could not create $git_tree: $!";
 184chdir($git_tree);
 185
 186my $orig_branch = "";
 187my $forward_master = 0;
 188my %branches;
 189
 190my $git_dir = $ENV{"GIT_DIR"} || ".git";
 191$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 192$ENV{"GIT_DIR"} = $git_dir;
 193my $orig_git_index;
 194$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 195my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 196                                    DIR => File::Spec->tmpdir());
 197close ($git_ih);
 198$ENV{GIT_INDEX_FILE} = $git_index;
 199my $maxnum = 0;
 200my $last_rev = "";
 201my $last_branch;
 202my $current_rev = $opt_s-1;
 203unless(-d $git_dir) {
 204        system("git-init-db");
 205        die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 206        system("git-read-tree");
 207        die "Cannot init an empty tree: $?\n" if $?;
 208
 209        $last_branch = $opt_o;
 210        $orig_branch = "";
 211} else {
 212        -f "$git_dir/refs/heads/$opt_o"
 213                or die "Branch '$opt_o' does not exist.\n".
 214                       "Either use the correct '-o branch' option,\n".
 215                       "or import to a new repository.\n";
 216
 217        -f "$git_dir/svn2git"
 218                or die "'$git_dir/svn2git' does not exist.\n".
 219                       "You need that file for incremental imports.\n";
 220        $last_branch = basename(readlink("$git_dir/HEAD"));
 221        unless($last_branch) {
 222                warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 223                $last_branch = "master";
 224        }
 225        $orig_branch = $last_branch;
 226        $last_rev = get_headref($orig_branch, $git_dir);
 227        if (-f "$git_dir/SVN2GIT_HEAD") {
 228                die <<EOM;
 229SVN2GIT_HEAD exists.
 230Make sure your working directory corresponds to HEAD and remove SVN2GIT_HEAD.
 231You may need to run
 232
 233    git-read-tree -m -u SVN2GIT_HEAD HEAD
 234EOM
 235        }
 236        system('cp', "$git_dir/HEAD", "$git_dir/SVN2GIT_HEAD");
 237
 238        $forward_master =
 239            $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 240            system('cmp', '-s', "$git_dir/refs/heads/master",
 241                                "$git_dir/refs/heads/$opt_o") == 0;
 242
 243        # populate index
 244        system('git-read-tree', $last_rev);
 245        die "read-tree failed: $?\n" if $?;
 246
 247        # Get the last import timestamps
 248        open my $B,"<", "$git_dir/svn2git";
 249        while(<$B>) {
 250                chomp;
 251                my($num,$branch,$ref) = split;
 252                $branches{$branch}{$num} = $ref;
 253                $branches{$branch}{"LAST"} = $ref;
 254                $current_rev = $num if $current_rev < $num;
 255        }
 256        close($B);
 257}
 258-d $git_dir
 259        or die "Could not create git subdir ($git_dir).\n";
 260
 261open BRANCHES,">>", "$git_dir/svn2git";
 262
 263sub node_kind($$$) {
 264        my ($branch, $path, $revision) = @_;
 265        my $pool=SVN::Pool->new;
 266        my $kind = $svn->{'svn'}->check_path(revert_split_path($branch,$path),$revision,$pool);
 267        $pool->clear;
 268        return $kind;
 269}
 270
 271sub revert_split_path($$) {
 272        my($branch,$path) = @_;
 273
 274        my $svnpath;
 275        $path = "" if $path eq "/"; # this should not happen, but ...
 276        if($branch eq "/") {
 277                $svnpath = "$trunk_name/$path";
 278        } elsif($branch =~ m#^/#) {
 279                $svnpath = "$tag_name$branch/$path";
 280        } else {
 281                $svnpath = "$branch_name/$branch/$path";
 282        }
 283
 284        return $svnpath
 285}
 286
 287sub get_file($$$) {
 288        my($rev,$branch,$path) = @_;
 289
 290        my $svnpath = revert_split_path($branch,$path);
 291
 292        # now get it
 293        my $name;
 294        if($opt_d) {
 295                my($req,$res);
 296
 297                # /svn/!svn/bc/2/django/trunk/django-docs/build.py
 298                my $url=$svn_url->clone();
 299                $url->path($url->path."/!svn/bc/$rev/$svn_dir$svnpath");
 300                print "... $path...\n" if $opt_v;
 301                $req = HTTP::Request->new(GET => $url);
 302                $res = $lwp_ua->request($req);
 303                if ($res->is_success) {
 304                        my $fh;
 305                        ($fh, $name) = tempfile('gitsvn.XXXXXX',
 306                        DIR => File::Spec->tmpdir(), UNLINK => 1);
 307                        print $fh $res->content;
 308                        close($fh) or die "Could not write $name: $!\n";
 309                } else {
 310                        return undef if $res->code == 301; # directory?
 311                        die $res->status_line." at $url\n";
 312                }
 313        } else {
 314                $name = $svn->file("/$svnpath",$rev);
 315                return undef unless defined $name;
 316        }
 317
 318        open my $F, '-|', "git-hash-object", "-w", $name
 319                or die "Cannot create object: $!\n";
 320        my $sha = <$F>;
 321        chomp $sha;
 322        close $F;
 323        unlink $name;
 324        my $mode = "0644"; # SV does not seem to store any file modes
 325        return [$mode, $sha, $path];
 326}
 327
 328sub split_path($$) {
 329        my($rev,$path) = @_;
 330        my $branch;
 331
 332        if($path =~ s#^/\Q$tag_name\E/([^/]+)/?##) {
 333                $branch = "/$1";
 334        } elsif($path =~ s#^/\Q$trunk_name\E/?##) {
 335                $branch = "/";
 336        } elsif($path =~ s#^/\Q$branch_name\E/([^/]+)/?##) {
 337                $branch = $1;
 338        } else {
 339                my %no_error = (
 340                        "/" => 1,
 341                        "/$tag_name" => 1,
 342                        "/$branch_name" => 1
 343                );
 344                print STDERR "$rev: Unrecognized path: $path\n" unless (defined $no_error{$path});
 345                return ()
 346        }
 347        $path = "/" if $path eq "";
 348        return ($branch,$path);
 349}
 350
 351sub copy_subdir($$$$$$) {
 352        # Somebody copied a whole subdirectory.
 353        # We need to find the index entries from the old version which the
 354        # SVN log entry points to, and add them to the new place.
 355
 356        my($newrev,$newbranch,$path,$oldpath,$rev,$new) = @_;
 357        my($branch,$srcpath) = split_path($rev,$oldpath);
 358
 359        my $gitrev = $branches{$branch}{$rev};
 360        unless($gitrev) {
 361                print STDERR "$newrev:$newbranch: could not find $oldpath \@ $rev\n";
 362                return;
 363        }
 364        print "$newrev:$newbranch:$path: copying from $branch:$srcpath @ $rev\n" if $opt_v;
 365        $srcpath =~ s#/*$#/#;
 366        open my $f,"-|","git-ls-tree","-r","-z",$gitrev,$srcpath;
 367        local $/ = "\0";
 368        while(<$f>) {
 369                chomp;
 370                my($m,$p) = split(/\t/,$_,2);
 371                my($mode,$type,$sha1) = split(/ /,$m);
 372                next if $type ne "blob";
 373                $p = substr($p,length($srcpath)-1);
 374                print "... found $path$p ...\n" if $opt_v;
 375                push(@$new,[$mode,$sha1,$path.$p]);
 376        }
 377        close($f) or
 378                print STDERR "$newrev:$newbranch: could not list files in $oldpath \@ $rev\n";
 379}
 380
 381sub commit {
 382        my($branch, $changed_paths, $revision, $author, $date, $message) = @_;
 383        my($author_name,$author_email,$dest);
 384        my(@old,@new);
 385
 386        if (not defined $author) {
 387                $author_name = $author_email = "unknown";
 388        } elsif ($author =~ /^(.*?)\s+<(.*)>$/) {
 389                ($author_name, $author_email) = ($1, $2);
 390        } else {
 391                $author =~ s/^<(.*)>$/$1/;
 392                $author_name = $author_email = $author;
 393        }
 394        $date = pdate($date);
 395
 396        my $tag;
 397        my $parent;
 398        if($branch eq "/") { # trunk
 399                $parent = $opt_o;
 400        } elsif($branch =~ m#^/(.+)#) { # tag
 401                $tag = 1;
 402                $parent = $1;
 403        } else { # "normal" branch
 404                # nothing to do
 405                $parent = $branch;
 406        }
 407        $dest = $parent;
 408
 409        my $prev = $changed_paths->{"/"};
 410        if($prev and $prev->[0] eq "A") {
 411                delete $changed_paths->{"/"};
 412                my $oldpath = $prev->[1];
 413                my $rev;
 414                if(defined $oldpath) {
 415                        my $p;
 416                        ($parent,$p) = split_path($revision,$oldpath);
 417                        if($parent eq "/") {
 418                                $parent = $opt_o;
 419                        } else {
 420                                $parent =~ s#^/##; # if it's a tag
 421                        }
 422                } else {
 423                        $parent = undef;
 424                }
 425        }
 426
 427        my $rev;
 428        if($revision > $opt_s and defined $parent) {
 429                open(H,"git-rev-parse --verify $parent |");
 430                $rev = <H>;
 431                close(H) or do {
 432                        print STDERR "$revision: cannot find commit '$parent'!\n";
 433                        return;
 434                };
 435                chop $rev;
 436                if(length($rev) != 40) {
 437                        print STDERR "$revision: cannot find commit '$parent'!\n";
 438                        return;
 439                }
 440                $rev = $branches{($parent eq $opt_o) ? "/" : $parent}{"LAST"};
 441                if($revision != $opt_s and not $rev) {
 442                        print STDERR "$revision: do not know ancestor for '$parent'!\n";
 443                        return;
 444                }
 445        } else {
 446                $rev = undef;
 447        }
 448
 449#       if($prev and $prev->[0] eq "A") {
 450#               if(not $tag) {
 451#                       unless(open(H,"> $git_dir/refs/heads/$branch")) {
 452#                               print STDERR "$revision: Could not create branch $branch: $!\n";
 453#                               $state=11;
 454#                               next;
 455#                       }
 456#                       print H "$rev\n"
 457#                               or die "Could not write branch $branch: $!";
 458#                       close(H)
 459#                               or die "Could not write branch $branch: $!";
 460#               }
 461#       }
 462        if(not defined $rev) {
 463                unlink($git_index);
 464        } elsif ($rev ne $last_rev) {
 465                print "Switching from $last_rev to $rev ($branch)\n" if $opt_v;
 466                system("git-read-tree", $rev);
 467                die "read-tree failed for $rev: $?\n" if $?;
 468                $last_rev = $rev;
 469        }
 470
 471        my $cid;
 472        if($tag and not %$changed_paths) {
 473                $cid = $rev;
 474        } else {
 475                my @paths = sort keys %$changed_paths;
 476                foreach my $path(@paths) {
 477                        my $action = $changed_paths->{$path};
 478
 479                        if ($action->[0] eq "A") {
 480                                my $f = get_file($revision,$branch,$path);
 481                                if($f) {
 482                                        push(@new,$f) if $f;
 483                                } elsif($action->[1]) {
 484                                        copy_subdir($revision,$branch,$path,$action->[1],$action->[2],\@new);
 485                                } else {
 486                                        my $opath = $action->[3];
 487                                        print STDERR "$revision: $branch: could not fetch '$opath'\n";
 488                                }
 489                        } elsif ($action->[0] eq "D") {
 490                                push(@old,$path);
 491                        } elsif ($action->[0] eq "M") {
 492                                my $f = get_file($revision,$branch,$path);
 493                                push(@new,$f) if $f;
 494                        } elsif ($action->[0] eq "R") {
 495                                # refer to a file/tree in an earlier commit
 496                                push(@old,$path); # remove any old stuff
 497
 498                                # ... and add any new stuff
 499                                my($b,$srcpath) = split_path($revision,$action->[1]);
 500                                $srcpath =~ s#/*$#/#;
 501                                open my $F,"-|","git-ls-tree","-r","-z", $branches{$b}{$action->[2]}, $srcpath;
 502                                local $/ = "\0";
 503                                while(<$F>) {
 504                                        chomp;
 505                                        my($m,$p) = split(/\t/,$_,2);
 506                                        my($mode,$type,$sha1) = split(/ /,$m);
 507                                        next if $type ne "blob";
 508                                        $p = substr($p,length($srcpath)-1);
 509                                        push(@new,[$mode,$sha1,$path.$p]);
 510                                }
 511                                close($F);
 512                        } else {
 513                                die "$revision: unknown action '".$action->[0]."' for $path\n";
 514                        }
 515                }
 516
 517                if(@old) {
 518                        open my $F, "-|", "git-ls-files", "-z", @old or die $!;
 519                        @old = ();
 520                        local $/ = "\0";
 521                        while(<$F>) {
 522                                chomp;
 523                                push(@old,$_);
 524                        }
 525                        close($F);
 526
 527                        while(@old) {
 528                                my @o2;
 529                                if(@old > 55) {
 530                                        @o2 = splice(@old,0,50);
 531                                } else {
 532                                        @o2 = @old;
 533                                        @old = ();
 534                                }
 535                                system("git-update-index","--force-remove","--",@o2);
 536                                die "Cannot remove files: $?\n" if $?;
 537                        }
 538                }
 539                while(@new) {
 540                        my @n2;
 541                        if(@new > 12) {
 542                                @n2 = splice(@new,0,10);
 543                        } else {
 544                                @n2 = @new;
 545                                @new = ();
 546                        }
 547                        system("git-update-index","--add",
 548                                (map { ('--cacheinfo', @$_) } @n2));
 549                        die "Cannot add files: $?\n" if $?;
 550                }
 551
 552                my $pid = open(C,"-|");
 553                die "Cannot fork: $!" unless defined $pid;
 554                unless($pid) {
 555                        exec("git-write-tree");
 556                        die "Cannot exec git-write-tree: $!\n";
 557                }
 558                chomp(my $tree = <C>);
 559                length($tree) == 40
 560                        or die "Cannot get tree id ($tree): $!\n";
 561                close(C)
 562                        or die "Error running git-write-tree: $?\n";
 563                print "Tree ID $tree\n" if $opt_v;
 564
 565                my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 566                my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 567                $pid = fork();
 568                die "Fork: $!\n" unless defined $pid;
 569                unless($pid) {
 570                        $pr->writer();
 571                        $pw->reader();
 572                        open(OUT,">&STDOUT");
 573                        dup2($pw->fileno(),0);
 574                        dup2($pr->fileno(),1);
 575                        $pr->close();
 576                        $pw->close();
 577
 578                        my @par = ();
 579                        @par = ("-p",$rev) if defined $rev;
 580
 581                        # loose detection of merges
 582                        # based on the commit msg
 583                        foreach my $rx (@mergerx) {
 584                                if ($message =~ $rx) {
 585                                        my $mparent = $1;
 586                                        if ($mparent eq 'HEAD') { $mparent = $opt_o };
 587                                        if ( -e "$git_dir/refs/heads/$mparent") {
 588                                                $mparent = get_headref($mparent, $git_dir);
 589                                                push @par, '-p', $mparent;
 590                                                print OUT "Merge parent branch: $mparent\n" if $opt_v;
 591                                        }
 592                                }
 593                        }
 594
 595                        exec("env",
 596                                "GIT_AUTHOR_NAME=$author_name",
 597                                "GIT_AUTHOR_EMAIL=$author_email",
 598                                "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 599                                "GIT_COMMITTER_NAME=$author_name",
 600                                "GIT_COMMITTER_EMAIL=$author_email",
 601                                "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 602                                "git-commit-tree", $tree,@par);
 603                        die "Cannot exec git-commit-tree: $!\n";
 604                }
 605                $pw->writer();
 606                $pr->reader();
 607
 608                $message =~ s/[\s\n]+\z//;
 609
 610                print $pw "$message\n"
 611                        or die "Error writing to git-commit-tree: $!\n";
 612                $pw->close();
 613
 614                print "Committed change $revision:$branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 615                chomp($cid = <$pr>);
 616                length($cid) == 40
 617                        or die "Cannot get commit id ($cid): $!\n";
 618                print "Commit ID $cid\n" if $opt_v;
 619                $pr->close();
 620
 621                waitpid($pid,0);
 622                die "Error running git-commit-tree: $?\n" if $?;
 623        }
 624
 625        if(not defined $dest) {
 626                print "... no known parent\n" if $opt_v;
 627        } elsif(not $tag) {
 628                print "Writing to refs/heads/$dest\n" if $opt_v;
 629                open(C,">$git_dir/refs/heads/$dest") and
 630                print C ("$cid\n") and
 631                close(C)
 632                        or die "Cannot write branch $dest for update: $!\n";
 633        }
 634
 635        if($tag) {
 636                my($in, $out) = ('','');
 637                $last_rev = "-" if %$changed_paths;
 638                # the tag was 'complex', i.e. did not refer to a "real" revision
 639
 640                $dest =~ tr/_/\./ if $opt_u;
 641
 642                my $pid = open2($in, $out, 'git-mktag');
 643                print $out ("object $cid\n".
 644                    "type commit\n".
 645                    "tag $dest\n".
 646                    "tagger $author_name <$author_email>\n") and
 647                close($out)
 648                    or die "Cannot create tag object $dest: $!\n";
 649
 650                my $tagobj = <$in>;
 651                chomp $tagobj;
 652
 653                if ( !close($in) or waitpid($pid, 0) != $pid or
 654                                $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 655                        die "Cannot create tag object $dest: $!\n";
 656                }
 657
 658                open(C,">$git_dir/refs/tags/$dest") and
 659                print C ("$tagobj\n") and
 660                close(C)
 661                        or die "Cannot create tag $branch: $!\n";
 662
 663                print "Created tag '$dest' on '$branch'\n" if $opt_v;
 664        }
 665        $branches{$branch}{"LAST"} = $cid;
 666        $branches{$branch}{$revision} = $cid;
 667        $last_rev = $cid;
 668        print BRANCHES "$revision $branch $cid\n";
 669        print "DONE: $revision $dest $cid\n" if $opt_v;
 670}
 671
 672my ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 673sub _commit_all {
 674        ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 675        my %p;
 676        while(my($path,$action) = each %$changed_paths) {
 677                $p{$path} = [ $action->action,$action->copyfrom_path, $action->copyfrom_rev, $path ];
 678        }
 679        $changed_paths = \%p;
 680}
 681
 682sub commit_all {
 683        my %done;
 684        my @col;
 685        my $pref;
 686        my $branch;
 687
 688        while(my($path,$action) = each %$changed_paths) {
 689                ($branch,$path) = split_path($revision,$path);
 690                next if not defined $branch;
 691                $done{$branch}{$path} = $action;
 692        }
 693        while(($branch,$changed_paths) = each %done) {
 694                commit($branch, $changed_paths, $revision, $author, $date, $message);
 695        }
 696}
 697
 698while(++$current_rev <= $svn->{'maxrev'}) {
 699        my $pool=SVN::Pool->new;
 700        $svn->{'svn'}->get_log("/",$current_rev,$current_rev,1,1,1,\&_commit_all,$pool);
 701        $pool->clear;
 702        commit_all();
 703        if($opt_l and not --$opt_l) {
 704                print STDERR "Stopping, because there is a memory leak (in the SVN library).\n";
 705                print STDERR "Please repeat this command; it will continue safely\n";
 706                last;
 707        }
 708}
 709
 710
 711unlink($git_index);
 712
 713if (defined $orig_git_index) {
 714        $ENV{GIT_INDEX_FILE} = $orig_git_index;
 715} else {
 716        delete $ENV{GIT_INDEX_FILE};
 717}
 718
 719# Now switch back to the branch we were in before all of this happened
 720if($orig_branch) {
 721        print "DONE\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 722        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 723                if $forward_master;
 724        unless ($opt_i) {
 725                system('git-read-tree', '-m', '-u', 'SVN2GIT_HEAD', 'HEAD');
 726                die "read-tree failed: $?\n" if $?;
 727        }
 728} else {
 729        $orig_branch = "master";
 730        print "DONE; creating $orig_branch branch\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 731        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 732                unless -f "$git_dir/refs/heads/master";
 733        unlink("$git_dir/HEAD");
 734        symlink("refs/heads/$orig_branch","$git_dir/HEAD");
 735        unless ($opt_i) {
 736                system('git checkout');
 737                die "checkout failed: $?\n" if $?;
 738        }
 739}
 740unlink("$git_dir/SVN2GIT_HEAD");
 741close(BRANCHES);