1#!/usr/bin/perl -w
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18use strict;
20use warnings;
21use Term::ReadLine;
22use Getopt::Long;
23use Text::ParseWords;
24use Data::Dumper;
25use Term::ANSIColor;
26use File::Temp qw/ tempdir tempfile /;
27use Error qw(:try);
28use Git;
29Getopt::Long::Configure qw/ pass_through /;
31package FakeTerm;
33sub new {
34 my ($class, $reason) = @_;
35 return bless \$reason, shift;
36}
37sub readline {
38 my $self = shift;
39 die "Cannot use readline on FakeTerm: $$self";
40}
41package main;
42sub usage {
45 print <<EOT;
46git send-email [options] <file | directory | rev-list options >
47 Composing:
49 --from <str> * Email From:
50 --to <str> * Email To:
51 --cc <str> * Email Cc:
52 --bcc <str> * Email Bcc:
53 --subject <str> * Email "Subject:"
54 --in-reply-to <str> * Email "In-Reply-To:"
55 --annotate * Review each patch that will be sent in an editor.
56 --compose * Open an editor for introduction.
57 Sending:
59 --envelope-sender <str> * Email envelope sender.
60 --smtp-server <str:int> * Outgoing SMTP server to use. The port
61 is optional. Default 'localhost'.
62 --smtp-server-port <int> * Outgoing SMTP server port.
63 --smtp-user <str> * Username for SMTP-AUTH.
64 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
65 --smtp-encryption <str> * tls or ssl; anything else disables.
66 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
67 Automating:
69 --identity <str> * Use the sendemail.<id> options.
70 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
71 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
72 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
73 --[no-]suppress-from * Send to self. Default off.
74 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default on.
75 --[no-]thread * Use In-Reply-To: field. Default on.
76 Administering:
78 --confirm <str> * Confirm recipients before sending;
79 auto, cc, compose, always, or never.
80 --quiet * Output one line of info per email.
81 --dry-run * Don't actually send the emails.
82 --[no-]validate * Perform patch sanity checks. Default on.
83 --[no-]format-patch * understand any non optional arguments as
84 `git format-patch` ones.
85EOT
87 exit(1);
88}
89# most mail servers generate the Date: header, but not all...
91sub format_2822_time {
92 my ($time) = @_;
93 my @localtm = localtime($time);
94 my @gmttm = gmtime($time);
95 my $localmin = $localtm[1] + $localtm[2] * 60;
96 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
97 if ($localtm[0] != $gmttm[0]) {
98 die "local zone differs from GMT by a non-minute interval\n";
99 }
100 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
101 $localmin += 1440;
102 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
103 $localmin -= 1440;
104 } elsif ($gmttm[6] != $localtm[6]) {
105 die "local time offset greater than or equal to 24 hours\n";
106 }
107 my $offset = $localmin - $gmtmin;
108 my $offhour = $offset / 60;
109 my $offmin = abs($offset % 60);
110 if (abs($offhour) >= 24) {
111 die ("local time offset greater than or equal to 24 hours\n");
112 }
113 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
115 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
116 $localtm[3],
117 qw(Jan Feb Mar Apr May Jun
118 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
119 $localtm[5]+1900,
120 $localtm[2],
121 $localtm[1],
122 $localtm[0],
123 ($offset >= 0) ? '+' : '-',
124 abs($offhour),
125 $offmin,
126 );
127}
128my $have_email_valid = eval { require Email::Valid; 1 };
130my $have_mail_address = eval { require Mail::Address; 1 };
131my $smtp;
132my $auth;
133sub unique_email_list(@);
135sub cleanup_compose_files();
136# Variables we fill in automatically, or via prompting:
138my (@to,@cc,@initial_cc,@bcclist,@xh,
139 $initial_reply_to,$initial_subject,@files,
140 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
141my $envelope_sender;
143# Example reply to:
145#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
146my $repo = eval { Git->repository() };
148my @repo = $repo ? ($repo) : ();
149my $term = eval {
150 $ENV{"GIT_SEND_EMAIL_NOTTY"}
151 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
152 : new Term::ReadLine 'git-send-email';
153};
154if ($@) {
155 $term = new FakeTerm "$@: going non-interactive";
156}
157# Behavior modification variables
159my ($quiet, $dry_run) = (0, 0);
160my $format_patch;
161my $compose_filename;
162# Handle interactive edition of files.
164my $multiedit;
165my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
166sub do_edit {
167 if (defined($multiedit) && !$multiedit) {
168 map {
169 system('sh', '-c', $editor.' "$@"', $editor, $_);
170 if (($? & 127) || ($? >> 8)) {
171 die("the editor exited uncleanly, aborting everything");
172 }
173 } @_;
174 } else {
175 system('sh', '-c', $editor.' "$@"', $editor, @_);
176 if (($? & 127) || ($? >> 8)) {
177 die("the editor exited uncleanly, aborting everything");
178 }
179 }
180}
181# Variables with corresponding config settings
183my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
184my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
185my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
186my ($validate, $confirm);
187my (@suppress_cc);
188my %config_bool_settings = (
190 "thread" => [\$thread, 1],
191 "chainreplyto" => [\$chain_reply_to, 1],
192 "suppressfrom" => [\$suppress_from, undef],
193 "signedoffbycc" => [\$signed_off_by_cc, undef],
194 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
195 "validate" => [\$validate, 1],
196);
197my %config_settings = (
199 "smtpserver" => \$smtp_server,
200 "smtpserverport" => \$smtp_server_port,
201 "smtpuser" => \$smtp_authuser,
202 "smtppass" => \$smtp_authpass,
203 "to" => \@to,
204 "cc" => \@initial_cc,
205 "cccmd" => \$cc_cmd,
206 "aliasfiletype" => \$aliasfiletype,
207 "bcc" => \@bcclist,
208 "aliasesfile" => \@alias_files,
209 "suppresscc" => \@suppress_cc,
210 "envelopesender" => \$envelope_sender,
211 "multiedit" => \$multiedit,
212 "confirm" => \$confirm,
213);
214# Handle Uncouth Termination
216sub signal_handler {
217 # Make text normal
219 print color("reset"), "\n";
220 # SMTP password masked
222 system "stty echo";
223 # tmp files from --compose
225 if (defined $compose_filename) {
226 if (-e $compose_filename) {
227 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
228 }
229 if (-e ($compose_filename . ".final")) {
230 print "'$compose_filename.final' contains the composed email.\n"
231 }
232 }
233 exit;
235};
236$SIG{TERM} = \&signal_handler;
238$SIG{INT} = \&signal_handler;
239# Begin by accumulating all the variables (defined above), that we will end up
241# needing, first, from the command line:
242my $rc = GetOptions("sender|from=s" => \$sender,
244 "in-reply-to=s" => \$initial_reply_to,
245 "subject=s" => \$initial_subject,
246 "to=s" => \@to,
247 "cc=s" => \@initial_cc,
248 "bcc=s" => \@bcclist,
249 "chain-reply-to!" => \$chain_reply_to,
250 "smtp-server=s" => \$smtp_server,
251 "smtp-server-port=s" => \$smtp_server_port,
252 "smtp-user=s" => \$smtp_authuser,
253 "smtp-pass:s" => \$smtp_authpass,
254 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
255 "smtp-encryption=s" => \$smtp_encryption,
256 "identity=s" => \$identity,
257 "annotate" => \$annotate,
258 "compose" => \$compose,
259 "quiet" => \$quiet,
260 "cc-cmd=s" => \$cc_cmd,
261 "suppress-from!" => \$suppress_from,
262 "suppress-cc=s" => \@suppress_cc,
263 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
264 "confirm=s" => \$confirm,
265 "dry-run" => \$dry_run,
266 "envelope-sender=s" => \$envelope_sender,
267 "thread!" => \$thread,
268 "validate!" => \$validate,
269 "format-patch!" => \$format_patch,
270 );
271unless ($rc) {
273 usage();
274}
275die "Cannot run git format-patch from outside a repository\n"
277 if $format_patch and not $repo;
278# Now, let's fill any that aren't set in with defaults:
280sub read_config {
282 my ($prefix) = @_;
283 foreach my $setting (keys %config_bool_settings) {
285 my $target = $config_bool_settings{$setting}->[0];
286 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
287 }
288 foreach my $setting (keys %config_settings) {
290 my $target = $config_settings{$setting};
291 if (ref($target) eq "ARRAY") {
292 unless (@$target) {
293 my @values = Git::config(@repo, "$prefix.$setting");
294 @$target = @values if (@values && defined $values[0]);
295 }
296 }
297 else {
298 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
299 }
300 }
301 if (!defined $smtp_encryption) {
303 my $enc = Git::config(@repo, "$prefix.smtpencryption");
304 if (defined $enc) {
305 $smtp_encryption = $enc;
306 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
307 $smtp_encryption = 'ssl';
308 }
309 }
310}
311# read configuration from [sendemail "$identity"], fall back on [sendemail]
313$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
314read_config("sendemail.$identity") if (defined $identity);
315read_config("sendemail");
316# fall back on builtin bool defaults
318foreach my $setting (values %config_bool_settings) {
319 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
320}
321# 'default' encryption is none -- this only prevents a warning
323$smtp_encryption = '' unless (defined $smtp_encryption);
324# Set CC suppressions
326my(%suppress_cc);
327if (@suppress_cc) {
328 foreach my $entry (@suppress_cc) {
329 die "Unknown --suppress-cc field: '$entry'\n"
330 unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
331 $suppress_cc{$entry} = 1;
332 }
333}
334if ($suppress_cc{'all'}) {
336 foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
337 $suppress_cc{$entry} = 1;
338 }
339 delete $suppress_cc{'all'};
340}
341# If explicit old-style ones are specified, they trump --suppress-cc.
343$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
344$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
345if ($suppress_cc{'body'}) {
347 foreach my $entry (qw (sob bodycc)) {
348 $suppress_cc{$entry} = 1;
349 }
350 delete $suppress_cc{'body'};
351}
352# Set confirm's default value
354my $confirm_unconfigured = !defined $confirm;
355if ($confirm_unconfigured) {
356 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
357};
358die "Unknown --confirm setting: '$confirm'\n"
359 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
360# Debugging, print out the suppressions.
362if (0) {
363 print "suppressions:\n";
364 foreach my $entry (keys %suppress_cc) {
365 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
366 }
367}
368my ($repoauthor, $repocommitter);
370($repoauthor) = Git::ident_person(@repo, 'author');
371($repocommitter) = Git::ident_person(@repo, 'committer');
372# Verify the user input
374foreach my $entry (@to) {
376 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
377}
378foreach my $entry (@initial_cc) {
380 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
381}
382foreach my $entry (@bcclist) {
384 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
385}
386sub parse_address_line {
388 if ($have_mail_address) {
389 return map { $_->format } Mail::Address->parse($_[0]);
390 } else {
391 return split_addrs($_[0]);
392 }
393}
394sub split_addrs {
396 return quotewords('\s*,\s*', 1, @_);
397}
398my %aliases;
400my %parse_alias = (
401 # multiline formats can be supported in the future
402 mutt => sub { my $fh = shift; while (<$fh>) {
403 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
404 my ($alias, $addr) = ($1, $2);
405 $addr =~ s/#.*$//; # mutt allows # comments
406 # commas delimit multiple addresses
407 $aliases{$alias} = [ split_addrs($addr) ];
408 }}},
409 mailrc => sub { my $fh = shift; while (<$fh>) {
410 if (/^alias\s+(\S+)\s+(.*)$/) {
411 # spaces delimit multiple addresses
412 $aliases{$1} = [ split(/\s+/, $2) ];
413 }}},
414 pine => sub { my $fh = shift; my $f='\t[^\t]*';
415 for (my $x = ''; defined($x); $x = $_) {
416 chomp $x;
417 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
418 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
419 $aliases{$1} = [ split_addrs($2) ];
420 }},
421 elm => sub { my $fh = shift;
422 while (<$fh>) {
423 if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
424 my ($alias, $addr) = ($1, $2);
425 $aliases{$alias} = [ split_addrs($addr) ];
426 }
427 } },
428 gnus => sub { my $fh = shift; while (<$fh>) {
430 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
431 $aliases{$1} = [ $2 ];
432 }}}
433);
434if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
436 foreach my $file (@alias_files) {
437 open my $fh, '<', $file or die "opening $file: $!\n";
438 $parse_alias{$aliasfiletype}->($fh);
439 close $fh;
440 }
441}
442($sender) = expand_aliases($sender) if defined $sender;
444# returns 1 if the conflict must be solved using it as a format-patch argument
446sub check_file_rev_conflict($) {
447 return unless $repo;
448 my $f = shift;
449 try {
450 $repo->command('rev-parse', '--verify', '--quiet', $f);
451 if (defined($format_patch)) {
452 print "foo\n";
453 return $format_patch;
454 }
455 die(<<EOF);
456File '$f' exists but it could also be the range of commits
457to produce patches for. Please disambiguate by...
458 * Saying "./$f" if you mean a file; or
460 * Giving --format-patch option if you mean a range.
461EOF
462 } catch Git::Error::Command with {
463 return 0;
464 }
465}
466# Now that all the defaults are set, process the rest of the command line
468# arguments and collect up the files that need to be processed.
469my @rev_list_opts;
470while (defined(my $f = shift @ARGV)) {
471 if ($f eq "--") {
472 push @rev_list_opts, "--", @ARGV;
473 @ARGV = ();
474 } elsif (-d $f and !check_file_rev_conflict($f)) {
475 opendir(DH,$f)
476 or die "Failed to opendir $f: $!";
477 push @files, grep { -f $_ } map { +$f . "/" . $_ }
479 sort readdir(DH);
480 closedir(DH);
481 } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
482 push @files, $f;
483 } else {
484 push @rev_list_opts, $f;
485 }
486}
487if (@rev_list_opts) {
489 die "Cannot run git format-patch from outside a repository\n"
490 unless $repo;
491 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
492}
493if ($validate) {
495 foreach my $f (@files) {
496 unless (-p $f) {
497 my $error = validate_patch($f);
498 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
499 }
500 }
501}
502if (@files) {
504 unless ($quiet) {
505 print $_,"\n" for (@files);
506 }
507} else {
508 print STDERR "\nNo patch files specified!\n\n";
509 usage();
510}
511sub get_patch_subject($) {
513 my $fn = shift;
514 open (my $fh, '<', $fn);
515 while (my $line = <$fh>) {
516 next unless ($line =~ /^Subject: (.*)$/);
517 close $fh;
518 return "GIT: $1\n";
519 }
520 close $fh;
521 die "No subject line in $fn ?";
522}
523if ($compose) {
525 # Note that this does not need to be secure, but we will make a small
526 # effort to have it be unique
527 $compose_filename = ($repo ?
528 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
529 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
530 open(C,">",$compose_filename)
531 or die "Failed to open for writing $compose_filename: $!";
532 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
535 my $tpl_subject = $initial_subject || '';
536 my $tpl_reply_to = $initial_reply_to || '';
537 print C <<EOT;
539From $tpl_sender # This line is ignored.
540GIT: Lines beginning in "GIT: " will be removed.
541GIT: Consider including an overall diffstat or table of contents
542GIT: for the patch you are writing.
543GIT:
544GIT: Clear the body content if you don't wish to send a summary.
545From: $tpl_sender
546Subject: $tpl_subject
547In-Reply-To: $tpl_reply_to
548EOT
550 for my $f (@files) {
551 print C get_patch_subject($f);
552 }
553 close(C);
554 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
556 if ($annotate) {
558 do_edit($compose_filename, @files);
559 } else {
560 do_edit($compose_filename);
561 }
562 open(C2,">",$compose_filename . ".final")
564 or die "Failed to open $compose_filename.final : " . $!;
565 open(C,"<",$compose_filename)
567 or die "Failed to open $compose_filename : " . $!;
568 my $need_8bit_cte = file_has_nonascii($compose_filename);
570 my $in_body = 0;
571 my $summary_empty = 1;
572 while(<C>) {
573 next if m/^GIT: /;
574 if ($in_body) {
575 $summary_empty = 0 unless (/^\n$/);
576 } elsif (/^\n$/) {
577 $in_body = 1;
578 if ($need_8bit_cte) {
579 print C2 "MIME-Version: 1.0\n",
580 "Content-Type: text/plain; ",
581 "charset=utf-8\n",
582 "Content-Transfer-Encoding: 8bit\n";
583 }
584 } elsif (/^MIME-Version:/i) {
585 $need_8bit_cte = 0;
586 } elsif (/^Subject:\s*(.+)\s*$/i) {
587 $initial_subject = $1;
588 my $subject = $initial_subject;
589 $_ = "Subject: " .
590 ($subject =~ /[^[:ascii:]]/ ?
591 quote_rfc2047($subject) :
592 $subject) .
593 "\n";
594 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
595 $initial_reply_to = $1;
596 next;
597 } elsif (/^From:\s*(.+)\s*$/i) {
598 $sender = $1;
599 next;
600 } elsif (/^(?:To|Cc|Bcc):/i) {
601 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
602 next;
603 }
604 print C2 $_;
605 }
606 close(C);
607 close(C2);
608 if ($summary_empty) {
610 print "Summary email is empty, skipping it\n";
611 $compose = -1;
612 }
613} elsif ($annotate) {
614 do_edit(@files);
615}
616sub ask {
618 my ($prompt, %arg) = @_;
619 my $valid_re = $arg{valid_re};
620 my $default = $arg{default};
621 my $resp;
622 my $i = 0;
623 return defined $default ? $default : undef
624 unless defined $term->IN and defined fileno($term->IN) and
625 defined $term->OUT and defined fileno($term->OUT);
626 while ($i++ < 10) {
627 $resp = $term->readline($prompt);
628 if (!defined $resp) { # EOF
629 print "\n";
630 return defined $default ? $default : undef;
631 }
632 if ($resp eq '' and defined $default) {
633 return $default;
634 }
635 if (!defined $valid_re or $resp =~ /$valid_re/) {
636 return $resp;
637 }
638 }
639 return undef;
640}
641my $prompting = 0;
643if (!defined $sender) {
644 $sender = $repoauthor || $repocommitter || '';
645 $sender = ask("Who should the emails appear to be from? [$sender] ",
646 default => $sender);
647 print "Emails will be sent from: ", $sender, "\n";
648 $prompting++;
649}
650if (!@to) {
652 my $to = ask("Who should the emails be sent to? ");
653 push @to, parse_address_line($to) if defined $to; # sanitized/validated later
654 $prompting++;
655}
656sub expand_aliases {
658 return map { expand_one_alias($_) } @_;
659}
660my %EXPANDED_ALIASES;
662sub expand_one_alias {
663 my $alias = shift;
664 if ($EXPANDED_ALIASES{$alias}) {
665 die "fatal: alias '$alias' expands to itself\n";
666 }
667 local $EXPANDED_ALIASES{$alias} = 1;
668 return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
669}
670@to = expand_aliases(@to);
672@to = (map { sanitize_address($_) } @to);
673@initial_cc = expand_aliases(@initial_cc);
674@bcclist = expand_aliases(@bcclist);
675if ($thread && !defined $initial_reply_to && $prompting) {
677 $initial_reply_to = ask(
678 "Message-ID to be used as In-Reply-To for the first email? ");
679}
680if (defined $initial_reply_to) {
681 $initial_reply_to =~ s/^\s*<?//;
682 $initial_reply_to =~ s/>?\s*$//;
683 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
684}
685if (!defined $smtp_server) {
687 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
688 if (-x $_) {
689 $smtp_server = $_;
690 last;
691 }
692 }
693 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
694}
695if ($compose && $compose > 0) {
697 @files = ($compose_filename . ".final", @files);
698}
699# Variables we set as part of the loop over files
701our ($message_id, %mail, $subject, $reply_to, $references, $message,
702 $needs_confirm, $message_num, $ask_default);
703sub extract_valid_address {
705 my $address = shift;
706 my $local_part_regexp = '[^<>"\s@]+';
707 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
708 # check for a local address:
710 return $address if ($address =~ /^($local_part_regexp)$/);
711 $address =~ s/^\s*<(.*)>\s*$/$1/;
713 if ($have_email_valid) {
714 return scalar Email::Valid->address($address);
715 } else {
716 # less robust/correct than the monster regexp in Email::Valid,
717 # but still does a 99% job, and one less dependency
718 $address =~ /($local_part_regexp\@$domain_regexp)/;
719 return $1;
720 }
721}
722# Usually don't need to change anything below here.
724# we make a "fake" message id by taking the current number
726# of seconds since the beginning of Unix time and tacking on
727# a random number to the end, in case we are called quicker than
728# 1 second since the last time we were called.
729# We'll setup a template for the message id, using the "from" address:
731my ($message_id_stamp, $message_id_serial);
733sub make_message_id
734{
735 my $uniq;
736 if (!defined $message_id_stamp) {
737 $message_id_stamp = sprintf("%s-%s", time, $$);
738 $message_id_serial = 0;
739 }
740 $message_id_serial++;
741 $uniq = "$message_id_stamp-$message_id_serial";
742 my $du_part;
744 for ($sender, $repocommitter, $repoauthor) {
745 $du_part = extract_valid_address(sanitize_address($_));
746 last if (defined $du_part and $du_part ne '');
747 }
748 if (not defined $du_part or $du_part eq '') {
749 use Sys::Hostname qw();
750 $du_part = 'user@' . Sys::Hostname::hostname();
751 }
752 my $message_id_template = "<%s-git-send-email-%s>";
753 $message_id = sprintf($message_id_template, $uniq, $du_part);
754 #print "new message id = $message_id\n"; # Was useful for debugging
755}
756$time = time - scalar $#files;
760sub unquote_rfc2047 {
762 local ($_) = @_;
763 my $encoding;
764 if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
765 $encoding = $1;
766 s/_/ /g;
767 s/=([0-9A-F]{2})/chr(hex($1))/eg;
768 }
769 return wantarray ? ($_, $encoding) : $_;
770}
771sub quote_rfc2047 {
773 local $_ = shift;
774 my $encoding = shift || 'utf-8';
775 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
776 s/(.*)/=\?$encoding\?q\?$1\?=/;
777 return $_;
778}
779# use the simplest quoting being able to handle the recipient
781sub sanitize_address
782{
783 my ($recipient) = @_;
784 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
785 if (not $recipient_name) {
787 return "$recipient";
788 }
789 # if recipient_name is already quoted, do nothing
791 if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
792 return $recipient;
793 }
794 # rfc2047 is needed if a non-ascii char is included
796 if ($recipient_name =~ /[^[:ascii:]]/) {
797 $recipient_name =~ s/^"(.*)"$/$1/;
798 $recipient_name = quote_rfc2047($recipient_name);
799 }
800 # double quotes are needed if specials or CTLs are included
802 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
803 $recipient_name =~ s/(["\\\r])/\\$1/g;
804 $recipient_name = "\"$recipient_name\"";
805 }
806 return "$recipient_name $recipient_addr";
808}
810sub send_message
812{
813 my @recipients = unique_email_list(@to);
814 @cc = (grep { my $cc = extract_valid_address($_);
815 not grep { $cc eq $_ } @recipients
816 }
817 map { sanitize_address($_) }
818 @cc);
819 my $to = join (",\n\t", @recipients);
820 @recipients = unique_email_list(@recipients,@cc,@bcclist);
821 @recipients = (map { extract_valid_address($_) } @recipients);
822 my $date = format_2822_time($time++);
823 my $gitversion = '@@GIT_VERSION@@';
824 if ($gitversion =~ m/..GIT_VERSION../) {
825 $gitversion = Git::version();
826 }
827 my $cc = join(", ", unique_email_list(@cc));
829 my $ccline = "";
830 if ($cc ne '') {
831 $ccline = "\nCc: $cc";
832 }
833 my $sanitized_sender = sanitize_address($sender);
834 make_message_id() unless defined($message_id);
835 my $header = "From: $sanitized_sender
837To: $to${ccline}
838Subject: $subject
839Date: $date
840Message-Id: $message_id
841X-Mailer: git-send-email $gitversion
842";
843 if ($reply_to) {
844 $header .= "In-Reply-To: $reply_to\n";
846 $header .= "References: $references\n";
847 }
848 if (@xh) {
849 $header .= join("\n", @xh) . "\n";
850 }
851 my @sendmail_parameters = ('-i', @recipients);
853 my $raw_from = $sanitized_sender;
854 $raw_from = $envelope_sender if (defined $envelope_sender);
855 $raw_from = extract_valid_address($raw_from);
856 unshift (@sendmail_parameters,
857 '-f', $raw_from) if(defined $envelope_sender);
858 if ($needs_confirm && !$dry_run) {
860 print "\n$header\n";
861 if ($needs_confirm eq "inform") {
862 $confirm_unconfigured = 0; # squelch this message for the rest of this run
863 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
864 print " The Cc list above has been expanded by additional\n";
865 print " addresses found in the patch commit message. By default\n";
866 print " send-email prompts before sending whenever this occurs.\n";
867 print " This behavior is controlled by the sendemail.confirm\n";
868 print " configuration setting.\n";
869 print "\n";
870 print " For additional information, run 'git send-email --help'.\n";
871 print " To retain the current behavior, but squelch this message,\n";
872 print " run 'git config --global sendemail.confirm auto'.\n\n";
873 }
874 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
875 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
876 default => $ask_default);
877 die "Send this email reply required" unless defined $_;
878 if (/^n/i) {
879 return;
880 } elsif (/^q/i) {
881 cleanup_compose_files();
882 exit(0);
883 } elsif (/^a/i) {
884 $confirm = 'never';
885 }
886 }
887 if ($dry_run) {
889 # We don't want to send the email.
890 } elsif ($smtp_server =~ m#^/#) {
891 my $pid = open my $sm, '|-';
892 defined $pid or die $!;
893 if (!$pid) {
894 exec($smtp_server, @sendmail_parameters) or die $!;
895 }
896 print $sm "$header\n$message";
897 close $sm or die $?;
898 } else {
899 if (!defined $smtp_server) {
901 die "The required SMTP server is not properly defined."
902 }
903 if ($smtp_encryption eq 'ssl') {
905 $smtp_server_port ||= 465; # ssmtp
906 require Net::SMTP::SSL;
907 $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
908 }
909 else {
910 require Net::SMTP;
911 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
912 ? "$smtp_server:$smtp_server_port"
913 : $smtp_server);
914 if ($smtp_encryption eq 'tls') {
915 require Net::SMTP::SSL;
916 $smtp->command('STARTTLS');
917 $smtp->response();
918 if ($smtp->code == 220) {
919 $smtp = Net::SMTP::SSL->start_SSL($smtp)
920 or die "STARTTLS failed! ".$smtp->message;
921 $smtp_encryption = '';
922 # Send EHLO again to receive fresh
923 # supported commands
924 $smtp->hello();
925 } else {
926 die "Server does not support STARTTLS! ".$smtp->message;
927 }
928 }
929 }
930 if (!$smtp) {
932 die "Unable to initialize SMTP properly. Is there something wrong with your config?";
933 }
934 if (defined $smtp_authuser) {
936 if (!defined $smtp_authpass) {
938 system "stty -echo";
940 do {
942 print "Password: ";
943 $_ = <STDIN>;
944 print "\n";
945 } while (!defined $_);
946 chomp($smtp_authpass = $_);
948 system "stty echo";
950 }
951 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
953 }
954 $smtp->mail( $raw_from ) or die $smtp->message;
956 $smtp->to( @recipients ) or die $smtp->message;
957 $smtp->data or die $smtp->message;
958 $smtp->datasend("$header\n$message") or die $smtp->message;
959 $smtp->dataend() or die $smtp->message;
960 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
961 }
962 if ($quiet) {
963 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
964 } else {
965 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
966 if ($smtp_server !~ m#^/#) {
967 print "Server: $smtp_server\n";
968 print "MAIL FROM:<$raw_from>\n";
969 print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
970 } else {
971 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
972 }
973 print $header, "\n";
974 if ($smtp) {
975 print "Result: ", $smtp->code, ' ',
976 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
977 } else {
978 print "Result: OK\n";
979 }
980 }
981}
982$reply_to = $initial_reply_to;
984$references = $initial_reply_to || '';
985$subject = $initial_subject;
986$message_num = 0;
987foreach my $t (@files) {
989 open(F,"<",$t) or die "can't open file $t";
990 my $author = undef;
992 my $author_encoding;
993 my $has_content_type;
994 my $body_encoding;
995 @cc = ();
996 @xh = ();
997 my $input_format = undef;
998 my @header = ();
999 $message = "";
1000 $message_num++;
1001 # First unfold multiline header fields
1002 while(<F>) {
1003 last if /^\s*$/;
1004 if (/^\s+\S/ and @header) {
1005 chomp($header[$#header]);
1006 s/^\s+/ /;
1007 $header[$#header] .= $_;
1008 } else {
1009 push(@header, $_);
1010 }
1011 }
1012 # Now parse the header
1013 foreach(@header) {
1014 if (/^From /) {
1015 $input_format = 'mbox';
1016 next;
1017 }
1018 chomp;
1019 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1020 $input_format = 'mbox';
1021 }
1022 if (defined $input_format && $input_format eq 'mbox') {
1024 if (/^Subject:\s+(.*)$/) {
1025 $subject = $1;
1026 }
1027 elsif (/^From:\s+(.*)$/) {
1028 ($author, $author_encoding) = unquote_rfc2047($1);
1029 next if $suppress_cc{'author'};
1030 next if $suppress_cc{'self'} and $author eq $sender;
1031 printf("(mbox) Adding cc: %s from line '%s'\n",
1032 $1, $_) unless $quiet;
1033 push @cc, $1;
1034 }
1035 elsif (/^Cc:\s+(.*)$/) {
1036 foreach my $addr (parse_address_line($1)) {
1037 if (unquote_rfc2047($addr) eq $sender) {
1038 next if ($suppress_cc{'self'});
1039 } else {
1040 next if ($suppress_cc{'cc'});
1041 }
1042 printf("(mbox) Adding cc: %s from line '%s'\n",
1043 $addr, $_) unless $quiet;
1044 push @cc, $addr;
1045 }
1046 }
1047 elsif (/^Content-type:/i) {
1048 $has_content_type = 1;
1049 if (/charset="?([^ "]+)/) {
1050 $body_encoding = $1;
1051 }
1052 push @xh, $_;
1053 }
1054 elsif (/^Message-Id: (.*)/i) {
1055 $message_id = $1;
1056 }
1057 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1058 push @xh, $_;
1059 }
1060 } else {
1062 # In the traditional
1063 # "send lots of email" format,
1064 # line 1 = cc
1065 # line 2 = subject
1066 # So let's support that, too.
1067 $input_format = 'lots';
1068 if (@cc == 0 && !$suppress_cc{'cc'}) {
1069 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1070 $_, $_) unless $quiet;
1071 push @cc, $_;
1072 } elsif (!defined $subject) {
1073 $subject = $_;
1074 }
1075 }
1076 }
1077 # Now parse the message body
1078 while(<F>) {
1079 $message .= $_;
1080 if (/^(Signed-off-by|Cc): (.*)$/i) {
1081 chomp;
1082 my ($what, $c) = ($1, $2);
1083 chomp $c;
1084 if ($c eq $sender) {
1085 next if ($suppress_cc{'self'});
1086 } else {
1087 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1088 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1089 }
1090 push @cc, $c;
1091 printf("(body) Adding cc: %s from line '%s'\n",
1092 $c, $_) unless $quiet;
1093 }
1094 }
1095 close F;
1096 if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1098 open(F, "$cc_cmd $t |")
1099 or die "(cc-cmd) Could not execute '$cc_cmd'";
1100 while(<F>) {
1101 my $c = $_;
1102 $c =~ s/^\s*//g;
1103 $c =~ s/\n$//g;
1104 next if ($c eq $sender and $suppress_from);
1105 push @cc, $c;
1106 printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1107 $c, $cc_cmd) unless $quiet;
1108 }
1109 close F
1110 or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1111 }
1112 if (defined $author and $author ne $sender) {
1114 $message = "From: $author\n\n$message";
1115 if (defined $author_encoding) {
1116 if ($has_content_type) {
1117 if ($body_encoding eq $author_encoding) {
1118 # ok, we already have the right encoding
1119 }
1120 else {
1121 # uh oh, we should re-encode
1122 }
1123 }
1124 else {
1125 push @xh,
1126 'MIME-Version: 1.0',
1127 "Content-Type: text/plain; charset=$author_encoding",
1128 'Content-Transfer-Encoding: 8bit';
1129 }
1130 }
1131 }
1132 $needs_confirm = (
1134 $confirm eq "always" or
1135 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1136 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1137 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1138 @cc = (@initial_cc, @cc);
1140 send_message();
1142 # set up for the next message
1144 if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1145 $reply_to = $message_id;
1146 if (length $references > 0) {
1147 $references .= "\n $message_id";
1148 } else {
1149 $references = "$message_id";
1150 }
1151 }
1152 $message_id = undef;
1153}
1154cleanup_compose_files();
1156sub cleanup_compose_files() {
1158 unlink($compose_filename, $compose_filename . ".final") if $compose;
1159}
1160$smtp->quit if $smtp;
1162sub unique_email_list(@) {
1164 my %seen;
1165 my @emails;
1166 foreach my $entry (@_) {
1168 if (my $clean = extract_valid_address($entry)) {
1169 $seen{$clean} ||= 0;
1170 next if $seen{$clean}++;
1171 push @emails, $entry;
1172 } else {
1173 print STDERR "W: unable to extract a valid address",
1174 " from: $entry\n";
1175 }
1176 }
1177 return @emails;
1178}
1179sub validate_patch {
1181 my $fn = shift;
1182 open(my $fh, '<', $fn)
1183 or die "unable to open $fn: $!\n";
1184 while (my $line = <$fh>) {
1185 if (length($line) > 998) {
1186 return "$.: patch contains a line longer than 998 characters";
1187 }
1188 }
1189 return undef;
1190}
1191sub file_has_nonascii {
1193 my $fn = shift;
1194 open(my $fh, '<', $fn)
1195 or die "unable to open $fn: $!\n";
1196 while (my $line = <$fh>) {
1197 return 1 if $line =~ /[^[:ascii:]]/;
1198 }
1199 return 0;
1200}